;Benutzen
Function items_use()
	Local slot
	For i=0 To 15
		If pl_items(i)=1 Then slot=i : Exit
	Next
	If pl_item(slot)-1=-1 Then msg("Hier ist kein Item!",1,2): Return 0
	Select pl_item(slot)-1
		;Blatt
		Case 1
			If pl_tileflora=52 Then
				If item_take(14,1, "gefüllt")
					items_delete()
				EndIf
			Else
				msg("Hier kann ich das nicht benutzen!")
			EndIf
		;Stein
		Case 2
			If item_take(9, 10, "hergestellt") Then
				items_delete()
			EndIf
		;Fleisch
		Case 5
			If pl_tilebuild=3 And pl_tilebuildb=0 Then
				If item_take(20, 1, "  ") Then
					items_delete()
				EndIf
			Else
				msg("Hier kann ich das nicht benutzen!")
			EndIf
		;Baumstamm
		Case 6
			If item_take(1, 10, "hergestellt") Then
				items_delete()
			EndIf
		;Korn
		Case 7
			If pl_tilex>=0 And pl_tilex<=msz And pl_tiley>=0 And pl_tiley<=msz
				If mapfree(pl_tilex, pl_tiley)=0 Then 
					If TerrainY(terrain, pl_tilex*15, 0, pl_tiley*15)>=7.5 Then
						freetile(pl_tilex,pl_tiley)
						terrain_flora_add(pl_tilex*15, 0, pl_tiley*15, 20, 0,0, 1)
						items_delete()
						For i=0 To 50
							effect_splatter((pl_tilex*15),camera_y#+5,(pl_tiley*15),Rnd(0.3,2),Rnd(-2,2),Rnd(1,3),Rnd(-2,2),80,255,80,1)
						Next
						msg("Getreide angepflanzt",1,1)
						mapfree(pl_tilex, pl_tiley)=1
						scantile()
					Else
						msg("Hier kannst du nichts anpflanzen!",1,2)
					EndIf
				Else
					msg("Hier kannst du nichts anpflanzen!",1,2)
				EndIf
			Else
				msg("Hier kannst du nichts anpflanzen!",1,2)
			EndIf
		;Blatt mit Wasser
		Case 13
			If pl_tileflora=20 Or pl_tileflora=21 Then
				For flora.flora = Each flora
					If Int(EntityX(flora\h)/15)=pl_tilex Then
						If Int(EntityZ(flora\h)/15)=pl_tiley Then
							flora\value=3
							If pl_tileflora=20 Then msg("Getreide gegossen",1,1)
							If pl_tileflora=21 Then msg("Hanf gegossen",1,1)
							items_delete()
						EndIf
					EndIf
				Next
			Else
				
			EndIf
		;Fisch
		Case 15
			If pl_tilebuild=3 And pl_tilebuildb=0  Then
				If item_take(22, 1, "  ") Then
					items_delete()
				EndIf
			Else
				msg("Hier kann ich das nicht benutzen!")
			EndIf
		;Hanf
		Case 16
			If pl_tilex>=0 And pl_tilex<=msz And pl_tiley>=0 And pl_tiley<=msz
				If mapfree(pl_tilex, pl_tiley)=0 Then 
					If TerrainY(terrain, pl_tilex*15, 0, pl_tiley*15)>=7.5 Then
						freetile(pl_tilex,pl_tiley)
						terrain_flora_add(pl_tilex*15, 0, pl_tiley*15, 21, 0,0, 1)
						items_delete()
						For i=0 To 50
							effect_splatter((pl_tilex*15),camera_y#+5,(pl_tiley*15),Rnd(0.3,2),Rnd(-2,2),Rnd(1,3),Rnd(-2,2),80,255,80,1)
						Next
						msg("Hanf angepflanzt",1,1)
						mapfree(pl_tilex, pl_tiley)=1
						scantile()
					Else
						msg("Hier kannst du nichts anpflanzen!",1,2)
					EndIf
				Else
					msg("Hier kannst du nichts anpflanzen!",1,2)
				EndIf
			Else
				msg("Hier kannst du nichts anpflanzen!",1,2)
			EndIf
		;kl. Fleisch  
		Case 18
			If pl_tilebuild=3 And pl_tilebuildb=0 Then
				If item_take(21, 1, "  ") Then
					items_delete()
				EndIf
			Else
				msg("Hier kann ich das nicht benutzen!")
			EndIf
		;Mehl
		Case 22
			If pl_tileflora=52 Then
				If item_take(24,1, "hergestellt")
					items_delete()
				EndIf
			Else
				msg("Hier kann ich das nicht benutzen!")
			EndIf
		;Teig
		Case 23
			If pl_tilebuild=3 And pl_tilebuildb=0 Then
				If item_take(25, 1, "gebacken") Then
					items_delete()
				EndIf
			Else
				msg("Hier kann ich das nicht benutzen!")
			EndIf
		;GummibeerenTeig
		Case 30
			If pl_tilebuild=3 And pl_tilebuildb=0 Then
				If item_take(32, 2, "gebacken") Then
					items_delete()
				EndIf
			Else
				msg("Hier kann ich das nicht benutzen!")
			EndIf
		;Nicht benutzbar
		Default
			x=Rand(0,8)
			Select x
				Case 0 msg("Wie soll ich das benutzen?")
				Case 1 msg("Was soll ich damit machen?")
				Case 2 msg("Keine Ahnung was ich damit machen könnte...")
				Case 3 msg("Ok, benutzen ... aber WIE?")
				Case 4 msg("Ne, damit kann ich leider nichts anfangen.")
				Case 5 msg("Damit kann ich nichts machen.")
				Case 6 msg("Was soll ich damit?")
				Case 7 msg("Ahja... benutzen - guter Witz!")
				Case 8 msg("Benutz dies, benutz das ... das hängt mir zum Hals raus!")
			End Select
	End Select
End Function

;Essen
Function items_eat()
	Local slot, item, value, def=0
	For i=0 To 15
		If pl_items(i)=1 Then slot=i : Exit
	Next
	If pl_item(slot)-1=-1 Then msg("Hier ist kein Item!",1,2): Return 0
	item=pl_item(slot)-1
	;Standart Nahrung
	If item_hunger(pl_item(slot)-1)>0 Then
		pl_hunger=pl_hunger-item_hunger(pl_item(slot)-1)
		pl_health=pl_health+item_health(pl_item(slot)-1)
		msg(item_name$(item)+" gegessen (+"+item_health(pl_item(slot)-1)+" Energie -"+item_hunger(pl_item(slot)-1)+" Hunger)",1,1)	
	Else
	;Spezial Nahrung
		Select item
			;Blatt mit Wasser
			Case 13
				pl_thirst=pl_thirst-40
				msg(item_name$(item)+" ausgetrunken (-40 Durst)",1,1)
			;Hanf
			Case 16
				pl_health=pl_health+2
				pl_hunger=pl_hunger-5
				pl_tired=pl_tired+5
				msg(item_name$(item)+" gegessen (+2 Energie +5 Müde -5 Hunger)",1,1)
			;Joint
			Case 17
				pl_hunger=pl_hunger-20
				pl_thirst=pl_thirst-20
				pl_tired=pl_tired+20
				pl_hi=pl_hi+1500
				msg(item_name$(item)+" geraucht (+20 Müde -20 Hunger -20 Durst)",1,1)
				For i=0 To 5
					effect_puff(camera_x#+Rnd(-1,1),camera_y#+Rnd(6,8),camera_z#+Rnd(-1,1),Rnd(0.05,0.1),150,150,150,Rnd(0.7,0.9), Rnd(0.02,0.03))
				Next
			;Gummibeeren
			Case 25
				pl_rubber=pl_rubber+400
				pl_hunger=pl_hunger-10
				pl_thirst=pl_thirst-10
				msg(item_name$(item)+" gegessen (-10 Hunger -10 Durst)",1,1)
			;Gummibeerenteig
			Case 30
				pl_rubber=pl_rubber+1300
				pl_hunger=pl_hunger-60
				pl_thirst=pl_thirst-10
				pl_health=pl_health+10
				msg(item_name$(item)+" gegessen (+10 Energie -60 Hunger -10 Durst)",1,1)
			;Gummibeerenkekse
			Case 31
				pl_rubber=pl_rubber+1500
				pl_hunger=pl_hunger-100
				pl_thirst=pl_thirst-10
				pl_health=pl_health+30
				msg(item_name$(item)+" gegessen (+40 Energie -100 Hunger -10 Durst)",1,1)
				
			
			;Nicht essbar
			Default
				def=1
				x=Rand(0,6)
				Select x
					Case 0 msg("Das kann ich nicht essen!")
					Case 1 msg("Igitt! Sowas esse ich nicht.")
					Case 2 msg("Ne ne, das ess ich nicht!")
					Case 3 msg("Buäh! Ich will was anständiges essen!")
					Case 4 msg("DAS ist NICHT essbar! Ahh!")
					Case 5 msg("Iss du es doch! Ich jedenfalls nicht!")
					Case 6 msg("Bevor ich DAS esse, sterbe ich lieber!")
				End Select
		End Select
	EndIf
	If def=0 Then
		items_delete()
	EndIf
End Function

;Löschen
Function items_delete(msg=0)
	Local slot
	For i=0 To 15
		If pl_items(i)=1 Then slot=i : Exit
	Next
	If (pl_item(slot))=0 Then Return 0
	Select pl_item(slot)-1
		Case 28
			If msg Then msg("Flieeeeg Schmetterling, flieg!",1,0)
			terrain_fauna_add(camera_x, 0, camera_z, 4)
		Default
			If msg Then msg(item_name$(pl_item(slot)-1)+" weggeworfen",1,2)
	End Select
	If pl_itemc(slot)>1 Then
		pl_itemc(slot)=pl_itemc(slot)-1
	Else
		pl_item(slot)=0
		pl_items(slot)=0
		pl_itemc(slot)=0
	EndIf
End Function

;Lagern
Function items_store()
	Local slot
	For i=0 To 15
		If pl_items(i)=1 Then slot=i : Exit
	Next
	If pl_item(slot)-1=-1 Then msg("Hier ist kein Item!",1,2): Return 0
	If item_hunger(pl_item(slot)-1)>0 Then
		For building.building = Each building
			If Int(EntityX(building\h1)/15)=pl_tilex Then
				If Int(EntityZ(building\h1)/15)=pl_tiley Then
					If building\typ=6 And pl_tilebuildb=0 Then
						building\mode=building\mode+item_hunger(pl_item(slot)-1)
						msg(item_name$(pl_item(slot)-1)+" eingelagert",1,1)
						items_delete()
						Return 1
					EndIf
				EndIf
			EndIf
		Next
	Else
		msg("Du kannst nur Nahrung lagern!",1,2)
	EndIf
	Return 0
End Function