;Items kombinieren
Function items_combine()
	Local i, slotcount, act=0
	slotcount=0
	For i=0 To 15
		If pl_items(i)=1 Then slotcount=slotcount+1
	Next
	Select slotcount
		;2 Slots gewählt
		Case 2
			;Beeren Matsch (Stein+Beeren)
			If items_csel(2)>0 And items_csel(4)>0 Then
				act=1
				If item_take(12, 1, "hergestellt") Then
					items_cdel(4)
				EndIf
			EndIf
			;Bananen Matsch (Stein+Bananen)
			If items_csel(2)>0 And items_csel(9)>0 Then
				act=1
				If item_take(13, 1, "hergestellt") Then
					items_cdel(9)
				EndIf
			EndIf
			;Hammer, Speer (Stein+Ast)
			If items_csel(2)>0 And items_csel(0)>0 Then
				;Hammer
				If tl_hammer=0 Then
					act=1
					tl_hammer=1
					items_cdel(2)
					items_cdel(0)
					msg("Hammer gebaut",0,3)
					PlaySound sfx_skill
				;Speer
				ElseIf tl_speer=0 Then
					act=1
					tl_speer=1
					items_cdel(2)
					items_cdel(0)
					msg("Speer gebaut",0,3)
					PlaySound sfx_skill			
				EndIf
			EndIf
			;Steinschleuder, Angel (Liane+Ast)
			If items_csel(3)>0 And items_csel(0)>0 Then
				;Steinschleuder
				If tl_stnschl=0 Then
					act=1
					tl_stnschl=1
					items_cdel(3)
					items_cdel(0)
					msg("Steinschleuder gebaut",0,3)
					PlaySound sfx_skill
				;Angel		
				ElseIf tl_angel=0 Then
					act=1
					tl_angel=1
					items_cdel(3)
					items_cdel(0)
					msg("Angel gebaut",0,3)
					PlaySound sfx_skill
				EndIf
			EndIf
			;Joint (Blatt+Hanf)
			If items_csel(1)>0 And items_csel(16)>0 Then
				act=1
				If item_take(18, 1, "gedreht") Then
					items_cdel(1)
					items_cdel(16)
				EndIf				
			EndIf
			;Mehl (Stein+Körner)
			If items_csel(2)>0 And items_csel(7)>0 Then
				act=1
				If items_csel(7)>=3 Then
					If item_take(23, 1, "hergestellt") Then
						items_cdel(7,3)
					EndIf
				Else
					msg("Du brauchst 3 Körner-Items dafür!",2,1)
				EndIf
			EndIf
			;Teig (Blatt mit Wasser+Mehl)
			If items_csel(13)>0 And items_csel(22)>0 Then
				act=1
				If item_take(24, 1, "hergestellt") Then
					items_cdel(13)
					items_cdel(22)
				EndIf
			EndIf
			;Gummibeerenteig (Teig+Gummibeeren)
			If items_csel(23)>0 And items_csel(25)>0 Then
				act = 1
				If items_csel(25)>=3
					If item_take(31, 1, "hergestellt") Then
						items_cdel(23)
						items_cdel(25,3)
					EndIf
				Else
					msg("Du brauchst 3 Gummibeeren dafür!",2,1)
				EndIf
			EndIf
			
	End Select
	;Kombinieren nicht möglich
	If act=0 Then
		i=Rand(0,12)
		Select i
			Case 0 msg("Wie soll ich das kombinieren?")
			Case 1 msg("Was soll ich da draus machen?")
			Case 2 msg("Keine Ahnung was ich da draus machen könnte...")
			Case 3 msg("Merkwürdige Ideen hast du!")
			Case 4 msg("Kombinieren? DAS?!")
			Case 5 msg("Ich würde das gerne kombinieren - wenn ich wüsste wie!")
			Case 6 msg("Wie soll ich das denn kombinieren du Held?")
			Case 7 msg("Ha ha - nein!")
			Case 8 msg("Leider nein, da draus wird nichts!")
			Case 9 msg("Ich kanns ja mal versuchen ... hmpf ne doch nicht.")
			Case 10 msg("Wenn du SO weiter machst verrecke ich bestimmt!")
			Case 11 msg("Tolle Idee, geht aber leider trotzdem nicht.")
			Case 12 msg("Naja ... Fantasie hast du schonmal :)")
		End Select
	EndIf
End Function

;Item gewählt? Wie oft vorhanden?
Function items_csel(typ)
	Local i
	For i=0 To 15
		If pl_items(i)=1 Then
			If pl_item(i)=typ+1 Then Return pl_itemc(i)
		EndIf
	Next
	Return 0
End Function

;Item löschen
Function items_cdel(typ, count=1)
	Local i, slot
	For i=0 To 15
		If pl_item(i)=typ+1 Then slot=i : Exit
	Next
	If (pl_item(slot))=0 Then Return 0
	If pl_itemc(slot)>count Then
		pl_itemc(slot)=pl_itemc(slot)-count
	Else
		pl_item(slot)=0
		pl_items(slot)=0
		pl_itemc(slot)=0
	EndIf
End Function